SUBROUTINE TYPE60 (TIME,XIN,OUT,T,DTDT,PAR,INFO,ICNTRL,*)
C***********************************************************************
C*    Copyright ASHRAE.  Toolkit for HVAC System Energy Calculations
C***********************************************************************
C*     SUBROUTINE:            PMPDET
C*
C*     LANGUAGE:              FORTRAN 77
C*
C*     PURPOSE:               Calculate the performance of a pump given
C*                            the entering fluid conditions and mass
C*                            flow rate.  Results include leaving fluid
C*                            pressure, and temperature, and
C*                            the fan energy consumption.  Calculations
C*                            are based on regression fits to pump head
C*                            and efficiency versus dimensionless flow.
C***********************************************************************
C*    INPUT VARIABLES  DESCRIPTION(UNITS)                        SAMPLE VALUES
C*    XIN(1)      M  Fluid flow rate(kg/s)                         5.0
C*    XIN(2)   PEnt  Entering pressure(Pa)                         0.0
C*    XIN(3)   TEnt  Entering temperature(C)                      25.0
C*    XIN(4)  Speed  Rotation speed(Hz)                           15.0
C*
C*    Note:   If M<0, TEnt is assumed to be fan outlet
C*            condition, TLvg is calculated inlet condition
C*
C*    OUTPUT VARIABLES
C*    OUT(1)   PLvg  Leaving pressure(Pa)                          4.722E5
C*    OUT(2)   TLvg  Leaving temperature(C)                      288.307  
C*    OUT(3)  Power  Power consumption(W)                          6.486E6
C*    OUT(4) ErrStat Error flag, 0=ok,1=error                      0.0 
C*
C*    PARAMETERS
C*    PAR(1) DiamWheel Diameter of impeller(m)                      .76
C*    PAR(2)   EffMot  Motor drive efficiency(-)                    .85
C*    PAR(3) MotorLoss Fraction of motor loss to fluid stream(-)   0.0
C*    Coef(i)Head   Array of coefficients for head vs flow curve
C*       head=coef0+coef1*flow+coef2*flow**2+coef3*flow**3+coef4*flow**4
C*    PAR(4)  COEF(0)HEAD                                          3.64
C*    PAR(5)  COEF(1)HEAD                                           .801
C*    PAR(6)  COEF(2)HEAD                                          -.19
C*    PAR(7)  COEF(3)HEAD                                          -.00445
C*    PAR(8)  COEF(4)HEAD                                          0.0
C*    Coef(i)Eff    Array of coefficients for efficiency curve
C*        eff=coef0+coef1*flow+coef2*flow**2+coef3*flow**3+coef4*flow**4
C*    PAR(9)   COEF(0)EFF                                          0.0
C*    PAR(10)  COEF(1)EFF                                           .564
C*    PAR(11)  COEF(2)EFF                                          -.0862
C*    PAR(12)  COEF(3)EFF                                          0.0
C*    PAR(13)  COEF(4)EFF                                          0.0 
C*
C*    PROPERTIES (MUST BE CHANGED IN THE DATA STATEMENT)
C*    CpLiq         Specific heat of fluid                      (J/kg C)
C*    RhoLiq        Fluid density                                (kg/m3)
C***********************************************************************
C     MAJOR RESTRICTIONS:     Assumes pump obeys affinity laws
C
C     DEVELOPER:              Michael J. Brandemuehl, PhD, PE
C                             University of Colorado at Boulder
C
C     DATE:                   January 1, 1992
C
C     INCLUDE FILES:          fanpmp.inc
C                             prop.inc
C     SUBROUTINES CALLED:     None
C     FUNCTIONS CALLED:       None
C
C     REVISION HISTORY:       None
C
C     REFERENCE:              Clark, D.R.  1985.  HVACSIM+ building
C                             systems and equipment simulation program:
C                             Reference Manual.  NBSIR 84-2996, National
C                             Institute of Standards and Technology,
C                             Washingtion, D.C.
C***********************************************************************
C     INTERNAL VARIABLES:
C     flow          Dimensionless flow coefficient                   (-)
C     head          Dimensionless pressure head coefficient          (-)
C     eff           Fan efficiency                                   (-)
C     hEnt          Entering air enthalpy                         (J/kg)
C     powShaft      Shaft power                                      (W)
C     qLoss         Heat transfer to fluid stream                    (W)
C     small         Small number used in place of zero
C***********************************************************************

	DOUBLE PRECISION XIN, OUT
      INTEGER ErrStat, INFO, IOPT, NI, NP, ND
      REAL PAR,DELTAP,SMALL,M,EFF,RHOLIQ,SPEED,DIAMWHEEL
      DIMENSION XIN(4),OUT(4),PAR(13), INFO(15)
	CHARACTER*3 YCHECK(4), OCHECK(4)

      DATA small/1.E-9/
      DATA RHOLIQ/998.0/,CPLIQ/4186.0/      
	DATA YCHECK/'MF2','PR3','TE1','NAV'/
	DATA OCHECK/'PR3','TE1','PW2','DM1'/

      ErrStat = 0
	IOPT	= -1
	NI		= 4		!CORRECT NUMBER OF INPUTS
	NP		= 13	!CORRECT NUMBER OF PARAMETERS
	ND		= 0		!CORRECT NUMBER OF DERIVATIVES
      
      M     = XIN(1)
      PENT  = XIN(2)
      TENT  = XIN(3)
      SPEED = XIN(4)

      DIAMWHEEL = PAR(1)
      EFFMOT    = PAR(2)
      MOTORLOSS = PAR(3)
      COEF0HEAD = PAR(4)
      COEF1HEAD = PAR(5)
      COEF2HEAD = PAR(6)
      COEF3HEAD = PAR(7)
      COEF4HEAD = PAR(8)
      COEF0EFF  = PAR(9)
      COEF1EFF  = PAR(10)
      COEF2EFF  = PAR(11)
      COEF3EFF  = PAR(12)
      COEF4EFF  = PAR(13)

	IF (INFO(7).EQ.-1) THEN
		CALL TYPECK(IOPT,INFO,NI,NP,ND)
C	 CHECKS TO SEE IF THE USER'S INFO MATCHES THE CORRECT NUMBERS
		CALL RCHECK(INFO,YCHECK,OCHECK)
C	 CHECKS TO SEE IF THE INPUT AND OUTPUT UNITS MATCH
	ENDIF

C1*** Calculate the dimensionless flow coefficient

      flow = ABS(M)/MAX(RhoLiq*Speed*DiamWheel**3.0, small)

C1*** Calculate the dimensionless head coefficient and efficiency

      head = Coef0Head+flow*(Coef1Head
     &                   +flow*(Coef2Head
     &                   +flow*(Coef3Head
     &                   +flow* Coef4Head)))
      eff = Coef0Eff+flow*(Coef1Eff
     &                 +flow*(Coef2Eff
     &                 +flow*(Coef3Eff
     &                 +flow* Coef4Eff)))

C1*** Calculate the power consumption

      powShaft = ABS(M)*head*Speed**2*DiamWheel**2/MAX(eff,small)
      Power = powShaft/EffMot

C1*** Calculate the leaving air conditions
C2*** If flow is zero, ABS(M) < small, the value of M is replaced with
C2*** small of the same sign as M in calculating hLvg

      deltaP = head*RhoLiq*Speed**2.0*DiamWheel**2.0
      PLvg = PEnt + SIGN(MAX(deltaP,small),M)

      qLoss = powShaft*(1-eff) + (Power-powShaft)*MotorLoss
      TLvg = TEnt + qLoss/SIGN(MAX(ABS(M),small),M)/CpLiq

      OUT(1) = PLvg
      OUT(2) = TLVG
      OUT(3) = POWER
      OUT(4) = ERRSTAT

      RETURN 1
      END