SUBROUTINE TYPE66 (TIME,XIN,OUT,T,DTDT,PAR,INFO,ICNTRL,*) 
C***********************************************************************
C*    Copyright ASHRAE.  Toolkit for HVAC System Energy Calculations
C*    Revised for TRNSYS by N.Blair and R.Schwarz
C**********************************************************************
C*    SUBROUTINE:             HEATEX
C*
C*    LANGUAGE:               FORTRAN 77
C*
C*    PURPOSE:                Calculate the outlet states of a simple
C*                            heat exchanger using the effectiveness-Ntu
C*                            method of analysis.
C***********************************************************************
C*    INPUT VARIABLES                                          Sample Values
C*    XIN(1) Cap1     Capacity rate of stream 1 (W/C)             5000.00    
C*    XIN(2) In1      Inlet state of stream 1 (C)                   25.00
C*    XIN(3) Cap2     Capacity rate of stream 2 (W/C)             4000.00
C*    XIN(4) In2      Inlet state of stream 2 (C)                    9.00
C*    XIN(5) UA       Overall heat transfer coefficient (W/C)     8200.00
C*    XIN(6) ConfigHX Heat exchanger configuration (-)               1.00
C*                  1 - Counterflow
C*                  2 - Parallel flow
C*                  3 - Cross flow, both streams unmixed
C*                  4 - Cross flow, both streams mixed
C*                  5 - Cross flow, stream 1 unmixed
C*                  6 - Cross flow, stream 2 unmixed
C*
C*    OUTPUT VARIABLES
C*    OUT(1) Out1     Outlet state of stream 1 (C)                  15.82
C*    OUT(2) Out2     Outlet state of stream 2 (C)                  20.47
C***********************************************************************
C     MAJOR RESTRICTIONS:     None
C
C     DEVELOPER:              Shauna Gabel
C                             Michael J. Brandemuehl, PhD, PE
C                             University of Colorado at Boulder
C
C     DATE:                   January 1, 1992
C
C     INCLUDE FILES:          None
C     SUBROUTINES CALLED:     None
C     FUNCTIONS CALLED:       None
C
C     REVISION HISTORY:       None
C
C     REFERENCE:              Kays, W.M. and A.L. London.  1964.
C                             Compact Heat Exchangers, 2nd Ed., McGraw-
C                             Hill:  New York.
C***********************************************************************
C*    INTERNAL VARIABLES:
C*    cMin          Minimum capacity rate of the streams (W/C)
C*    cMax          Maximum capacity rate of the streams (W/C)
C*    cRatio        Ratio of minimum to maximum capacity rate
C*    ntu           Number of transfer units (-)
C*    effectiveness Heat exchanger effectiveness (-)
C*    qMax          Maximum heat transfer possible (W)
C***********************************************************************
	DOUBLE PRECISION XIN, OUT
	INTEGER INFO, IOPT, NI, NP, ND
      REAL ntu,qMax,large
      DIMENSION XIN(6),OUT(2),INFO(15)
	CHARACTER*3 YCHECK(6), OCHECK(2)
	]
      DATA small/1.E-15/, large/1.E15/
	DATA YCHECK/'NAV','TE1','NAV','TE1','NAV','DM1'/
	DATA OCHECK/'TE1','TE1'/

	IOPT	= -1
	NI		= 6		!CORRECT NUMBER OF INPUTS
	NP		= 0		!CORRECT NUMBER OF PARAMETERS
	ND		= 0		!CORRECT NUMBER OF DERIVATIVES

      CAP1     = XIN(1)
      IN1      = XIN(2)
      CAP2     = XIN(3)
      IN2      = XIN(4)
      UA       = XIN(5)
      ConfigHX = XIN(6)
	
      IF (INFO(7).EQ.-1) THEN
		CALL TYPECK(IOPT,INFO,NI,NP,ND)
C	CHECKS TO SEE IF USER'S INFO MATCHES CORRECT NUMBERS
		CALL RCHECK(INFO,YCHECK,OCHECK)
C	CHECKS TO SEE IF INPUT AND OUTPUT UNITS MATCH
	ENDIF 

C1*** Ntu and Cmin/Cmax (cRatio) calculations

      cMin = MIN(Cap1,Cap2)
      cMax = MAX(Cap1,Cap2)

      IF( cMax .EQ. 0.) THEN
        cRatio = 1.
      ELSE
        cRatio = cMin/cMax
      ENDIF

      IF( cMin .EQ. 0.) THEN
        ntu = large
      ELSE
        ntu = ua/cMin
      ENDIF

C1*** Calculate effectiveness for special limiting cases

      mode = NINT(ConfigHX)

      IF(ntu .LE. 0) THEN

        effectiveness = 0.

      ELSE IF(cRatio .LT. small) THEN

C2*** Cmin/Cmax = 0 and effectiveness is independent of configuration

        effectiveness = 1 - EXP(-ntu)

C1*** Calculate effectiveness depending on heat exchanger configuration

      ELSE IF (mode .EQ. 1) THEN

C2*** Counterflow

        IF (ABS(cRatio-1.) .LT. small) THEN
          effectiveness = ntu/(ntu+1.)
        ELSE
          e=EXP(-ntu*(1-cRatio))
          effectiveness = (1-e)/(1-cRatio*e)
        ENDIF

      ELSE IF (mode .EQ. 2) THEN

C2*** Parallel flow

        effectiveness = (1-EXP(-ntu*(1+cRatio)))/(1+cRatio)

      ELSE IF (mode .EQ. 3) THEN

C2*** Cross flow, both streams unmixed

        eta = ntu**(-0.22)
        effectiveness = 1 - EXP((EXP(-ntu*cRatio*eta)-1)/(cRatio*eta))

      ELSE IF (mode .EQ. 4) THEN

C2*** Cross flow, both streams mixed

        effectiveness = ((1/(1-EXP(-ntu)))+
     &                  (cRatio/(1-EXP(-ntu*cRatio)))-(1/(-ntu)))**(-1)

      ELSE

C2*** One stream is mixed and one is unmixed.  Determine whether the
C2*** minimum or maximum capacity rate stream is mixed.

        IF ( (ABS(Cap1-cMin).LT.small .AND. mode.EQ.5) .OR.
     &       (ABS(Cap2-cMin).LT.small .AND. mode.EQ.6) ) THEN

C2*** Cross flow, stream with minimum capacity rate unmixed

          effectiveness = (1-EXP(-cRatio*(1-EXP(-ntu))))/cRatio

        ELSE

C2*** Cross flow, stream with maximum capacity rate unmixed

          effectiveness = 1-EXP(-(1-EXP(-ntu*cRatio))/cRatio)

        ENDIF

      ENDIF

C1*** Determine leaving conditions for the two streams

      qMax = MAX(cMin,small)*(In1-In2)
      Out1 = In1 - effectiveness*qMax/MAX(Cap1,small)
      Out2 = In2 + effectiveness*qMax/MAX(Cap2,small)

      OUT(1)=OUT1
      OUT(2)=OUT2      

      RETURN 1
      END