C
C     SIMPLIFIED MODEL OF LA CHAUMIERE BUILDING
C      EXERCISE A.1 OF ANNEX17 
C      DOC AN17-880725-01
C
C        1. LIVING ROOM
C        2. SMALL ROOM
C        3. BEDROOM
C        4. KITCHEN
C        5. HALL+BATHROOM
C 
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C
C     SAMPLE INPUT AND OUTPUT VALUES
C
C     PARAMETERS                               SAMPLE VALUES
C     NONE
C
C     DERIVATIVES (tolerance = .00001)
C     D 1      Living room temperature              16.0
C     D 2      Small room temperature               18.0
C     D 3      Bedroom room temperature             16.5
C     D 4      Kitchen room temperature             18.5
C     D 5      Bathroom room temperature            17.0
C     D 6      Living room structure temp.          19.0
C     D 7      Small room structure temp.           15.0
C     D 8      Bedroom structure temp.              19.5
C     D 9      Kitchen structure temp.              17.0
C     D 10     Bathroom structure temp.             20.0
C
C     INPUTS
C     XIN(1)  Outside temperature                   17.0
C     XIN(2)  Eq. sol-air temp. living room         16.5
C     XIN(3)  Eq. sol-air temp. small room          17.0
C     XIN(4)  Eq. sol-air temp. bedroom             15.3
C     XIN(5)  Eq. sol-air temp. kitchen             19.0
C     XIN(6)  Heat gains in living room             24.0
C     XIN(7)  Heat gains in small room              60.0
C     XIN(8)  Heat gains in bedroom                120.0
C     XIN(9)  Heat gains in kitchen                 30.0
C     XIN(10) Heat gains in bath room               40.0
C     XIN(11) Heating in living room               400.0
C     XIN(12) Heating in small room                350.0
C     XIN(13) Heating in bedroom                   500.0
C     XIN(14) Heating in kitchen                   450.0
C     XIN(15) Heating in bath room                 475.0
C
C     OUTPUTS
C     OUT(1)  Living room temperature               18.99
C     OUT(2)  Small room temperature                15.02
C     OUT(3)  Bedroom temperature                   19.49
C     OUT(4)  Kitchen temperature                   17.01
C     OUT(5)  Bathroom temperature                  19.99
C     OUT(6)  Living room structure temperature     16.00
C     OUT(7)  Small room structure temperature      18.00
C     OUT(8)  Bedroom structure temperature         16.5
C     OUT(9)  Kitchen structure temperature         18.50
C     OUT(10) Bathroom structure temperature        17.00
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC

!  This component has been assigned Type Number 208. If that number conflicts with 
!  another user Type number, you will need to change it and recompile the appropriate
!  dll.

      SUBROUTINE TYPE208(TIME,XIN,OUT,T,DTDT,PAR,INFO,ICNTRL,*)

!DEC$ATTRIBUTES DLLEXPORT :: TYPE208


C
      DOUBLE PRECISION XIN,OUT
	DIMENSION DTDT(10),T(10),CS(5),CI(5),TWS(5),TWI(5),
     .Q(5),RO(5),RI(5),RW(5),R(5,5),QV(5),QI(5),QL(5),QH(5),
     .OUT(20),XIN(15),INFO(15),TO(5)
C                  DONNEES PROPRES A LA CHAUMIERE
C
C             CS : STRUCTURE CAPACITANCES
C
      DATA CS/14741733.,9131091.,9638070.,7423188.,8642000./
C
C             CI : ZONE CAPACITANCES      
C
      DATA CI/77068.,35962.,47527.,32112.,38530./
C             
C             RW : WINDOWS RESISTANCES
C
      DATA RW/5.252E-2,0.1168,0.06684,0.1245,1E+10/
C
C             RO : OUTSIDE-STRUCTURE RESISTANCES
C
      DATA RO/1.085E-1,0.4334E-1,1.214E-1,1.494E-1,1E+10/
C
C             RI : STRUCTURE-ZONE RESISTANCES
C
      DATA RI/2.187E-3,4.280E-3,3.217E-3,4.052E-3,3.319E-3/
C
C             R  : RESISTANCES BETWEEEN ZONES
C
      DATA R/1.,       7.931E-2, 6.943E-2, 1E+15,    5.553E-2,
     .       7.931E-2, 1.,       5.553E-2, 1E+15,    1E+15,
     .       6.943E-2, 5.553E-2, 1.,       5.553E-2, 4.442E-1,
     .       1E+15,    1E+15,    5.553E-2, 1.,       8.885E-2,
     .       5.553E-2, 1E+15,    4.442E-1, 8.885E-2, 1./


!    Set the version information for TRNSYS
      IF (INFO(7).EQ.-2) THEN
	  INFO(12) = 15
	  RETURN 1
	ENDIF

C 
C                  PARAMETERS
C
C        
C                  INPUTS
C
C             OUTSIDE TEMPERATURE
      TOUT=XIN(1)
C
C                  EQUIVALENT SOL AIR TEMPERATURE
C

C
      TO(1)=XIN(2)
C
      TO(2)=XIN(3)
C
      TO(3)=XIN(4)
C
      TO(4)=XIN(5)
C
      TO(5)=0.
C 
C             LOAD : QL(I)
C
      DO 50 I=1,5
      QL(I)=XIN(I+5)
 50   CONTINUE    
C
C             HEATING : QH(I)  (RADIATOR+PIPE)
C 
      DO 60 I=1,5
      QH(I)=XIN(I+10)
 60   CONTINUE
C  
C
C                  TOTAL  LOAD : Q(I) 
C
      DO 20 I=1,5
      Q(I)=QL(I)+QH(I)               
 20   CONTINUE
C
C                  BUILDING EQUATIONS
C
      DO 10 I=1,5
      DTDT(I)=(1/CS(I))*((TO(I)-T(I))/RO(I)+(T(I+5)-T(I))/RI(I))
      DTDT(I+5)=(1/CI(I))*((T(I)-T(I+5))/RI(I)
     .+(TO(I)-T(I+5))/RW(I)
     .+(T(6)-T(I+5))/R(I,1)
     .+(T(7)-T(I+5))/R(I,2)
     .+(T(8)-T(I+5))/R(I,3)
     .+(T(9)-T(I+5))/R(I,4)
     .+(T(10)-T(I+5))/R(I,5)
     .+Q(I)) 
 10   CONTINUE
C
C                  OUTPUTS    
C
      DO 30 I=1,5
      OUT(I)=T(I+5)
      OUT(I+5)=T(I)
      OUT(I+15)=Q(I)
 30   CONTINUE
C
      RETURN 1
      END